aboutsummaryrefslogtreecommitdiff
path: root/meson.build
blob: bb4e98a8e3f951394db77f6b0aa6d4bc40197602 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
project('vm.lv2', 'c', default_options : [
	'buildtype=release',
	'warning_level=3',
	'werror=false',
	'b_lto=false',
	'c_std=gnu11'])

nk_pugl = subproject('nk_pugl')

lv2libdir = get_option('lv2libdir')

inst_dir = join_paths(lv2libdir, meson.project_name())

nk_pugl_dep = nk_pugl.get_variable('nk_pugl_gl')
cousine_regular_ttf = nk_pugl.get_variable('cousine_regular_ttf')

source_root = meson.source_root()
build_root = meson.build_root()

static_link = meson.is_cross_build()

cc = meson.get_compiler('c')

m_dep = cc.find_library('m')
lv2_dep = dependency('lv2', version : '>=1.14.0')

dsp_deps = [m_dep, lv2_dep]
ui_deps = [m_dep, lv2_dep, nk_pugl_dep]

props_inc = include_directories('props.lv2')
timely_inc = include_directories('timely.lv2')
inc_dir = [props_inc, timely_inc]

rawvers = run_command('cat', 'VERSION').stdout().strip()
version = rawvers.split('.')

conf_data = configuration_data()
conf_data.set('MAJOR_VERSION', version[0])
conf_data.set('MINOR_VERSION', version[1])
conf_data.set('MICRO_VERSION', version[2])

add_project_arguments('-DVM_VERSION="'+rawvers+'"', language : 'c')
add_project_arguments('-D_GNU_SOURCE', language : 'c')

lv2_validate = find_program('lv2_validate', native : true, required : false)
sord_validate = find_program('sord_validate', native : true, required : false)
lv2lint = find_program('lv2lint', required : false)

dsp_srcs = ['vm.c']

ui_srcs = ['vm_ui.c']

c_args = [
	'-fvisibility=hidden']

if host_machine.system() == 'windows'
	conf_data.set('UI_TYPE', 'WindowsUI')
elif host_machine.system() == 'darwin'
	conf_data.set('UI_TYPE', 'CocoaUI')
else
	conf_data.set('UI_TYPE', 'X11UI')
endif

mod = shared_module('vm', dsp_srcs,
	c_args : c_args,
	include_directories : inc_dir,
	name_prefix : '',
	dependencies : dsp_deps,
	install : true,
	install_dir : inst_dir)

ui = shared_module('vm_ui', ui_srcs,
	c_args : c_args,
	include_directories : inc_dir,
	name_prefix : '',
	dependencies : ui_deps,
	install : true,
	install_dir : inst_dir)

suffix = mod.full_path().strip().split('.')[-1]
conf_data.set('MODULE_SUFFIX', '.' + suffix)

manifest_ttl = configure_file(
	input : 'manifest.ttl.in',
	output : 'manifest.ttl',
	configuration : conf_data,
	install : true,
	install_dir : inst_dir)

dsp_ttl = configure_file(
	input : 'vm.ttl',
	output : 'vm.ttl',
	copy : true,
	install : true,
	install_dir : inst_dir)

ui_ttl = configure_file(
	input : 'vm_ui.ttl',
	output : 'vm_ui.ttl',
	copy : true,
	install : true,
	install_dir : inst_dir)

configure_file(
	input : cousine_regular_ttf,
	output : 'Cousine-Regular.ttf',
	copy : true,
	install : true,
	install_dir : inst_dir)
configure_file(
	input : join_paths('png', 'cancel.png'),
	output : 'cancel.png',
	copy : true,
	install : true,
	install_dir : inst_dir)
configure_file(
	input : join_paths('png', 'plus.png'),
	output : 'plus.png',
	copy : true,
	install : true,
	install_dir : inst_dir)
configure_file(
	input : join_paths('png', 'up_arrow.png'),
	output : 'up_arrow.png',
	copy : true,
	install : true,
	install_dir : inst_dir)

if lv2_validate.found() and sord_validate.found()
	test('LV2 validate', lv2_validate,
		args : [manifest_ttl, dsp_ttl, ui_ttl])
endif

if lv2lint.found()
	test('LV2 lint', lv2lint,
		args : ['-I', join_paths(build_root, ''),
			'-Ewarn',
			'http://open-music-kontrollers.ch/lv2/vm#atom',
			'http://open-music-kontrollers.ch/lv2/vm#audio',
			'http://open-music-kontrollers.ch/lv2/vm#control',
			'http://open-music-kontrollers.ch/lv2/vm#cv',
			'http://open-music-kontrollers.ch/lv2/vm#midi'])
endif