aboutsummaryrefslogtreecommitdiff
path: root/meson.build
blob: 948e6991e9e5926e197f0fcccf6d39a2a48df3ce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
project('router.lv2', 'c', default_options : [
	'buildtype=release',
	'warning_level=1',
	'werror=false',
	'b_lto=false',
	'c_std=c11'])

add_project_arguments('-D_GNU_SOURCE', language : 'c')

conf_data = configuration_data()
cc = meson.get_compiler('c')
lv2_validate = find_program('lv2_validate', native : true, required : false)
lv2lint = find_program('lv2lint', required : false)

m_dep = cc.find_library('m')
lv2_dep = dependency('lv2', version : '>=1.14.0')

inc_dir = include_directories('props.lv2')

inst_dir = join_paths(get_option('libdir'), 'lv2', meson.project_name())

mod = shared_module('router',
	'router.c',
	'router_atom_bouncer.c',
	'router_atom_deflector.c',
	'router_atom_sprinkler.c',
	'router_audio_bouncer.c',
	'router_audio_deflector.c',
	'router_audio_sprinkler.c',
	c_args : ['-fvisibility=hidden', '-ffast-math'],
	include_directories : inc_dir,
	name_prefix : '',
	dependencies : [m_dep, lv2_dep],
	install : true,
	install_dir : inst_dir)

version = run_command('cat', 'VERSION').stdout().strip().split('.')
conf_data.set('MAJOR_VERSION', version[0])
conf_data.set('MINOR_VERSION', version[1])
conf_data.set('MICRO_VERSION', version[2])

suffix = mod.full_path().strip().split('.')[-1]
conf_data.set('MODULE_SUFFIX', '.' + suffix)

manifest_ttl = configure_file(input : 'manifest.ttl.in', output : 'manifest.ttl',
	configuration : conf_data,
	install : true,
	install_dir : inst_dir)
router_ttl = configure_file(input : 'router.ttl.in', output : 'router.ttl',
	configuration : conf_data,
	install : true,
	install_dir : inst_dir)

if lv2_validate.found()
	test('LV2 validate', lv2_validate,
		args : [manifest_ttl, router_ttl])
endif

if lv2lint.found()
	test('LV2 lint', lv2lint,
		args : ['-Swarn',
			'http://open-music-kontrollers.ch/lv2/router#atom_bouncer',
			'http://open-music-kontrollers.ch/lv2/router#atom_deflector',
			'http://open-music-kontrollers.ch/lv2/router#atom_sprinkler',
			'http://open-music-kontrollers.ch/lv2/router#audio_bouncer',
			'http://open-music-kontrollers.ch/lv2/router#audio_bouncer_2',
			'http://open-music-kontrollers.ch/lv2/router#audio_deflector',
			'http://open-music-kontrollers.ch/lv2/router#audio_deflector_2',
			'http://open-music-kontrollers.ch/lv2/router#audio_sprinkler',
			'http://open-music-kontrollers.ch/lv2/router#audio_sprinkler_2',
			'http://open-music-kontrollers.ch/lv2/router#cv_bouncer',
			'http://open-music-kontrollers.ch/lv2/router#cv_deflector',
			'http://open-music-kontrollers.ch/lv2/router#cv_sprinkler'])
endif